// colour setting

$puts(line,$char(3)10b010|00ff00$char(3))
$puts(shadow,$char(3)606860|808080$char(3))
$puts(default,$if(%_isplaying%,$char(3)00e0e0|40ffff$char(3),$char(3)b0b0b0|ffffff$char(3)))
$puts(gradation0,$char(3)f0f0f0|ffffff$char(3))
$puts(gradation1,$char(3)d8d8d8|e8e8e8$char(3))
$puts(gradation2,$char(3)c0c0c0|d0d0d0$char(3))
$puts(gradation3,$char(3)a8a8a8|b8b8b8$char(3))
$puts(gradation4,$char(3)909090|a0a0a0$char(3))
$puts(gradation5,$char(3)787878|888888$char(3))


// decision about album and single

$if(%album%,
$if($strcmp($num(%tracknumber%,2),01),$puts(first,1))
$if($strcmp($num(%tracknumber%,2),02),$puts(second,1))
$if($strcmp($num(%tracknumber%,2),03),$puts(third,1))
$if($strcmp($num(%tracknumber%,2),04),$puts(fourth,1)))
$if($or(
$not(%album%),$stricmp($num(%tracknumber%,2),00),
$and(%album%,$not(%tracknumber%)),$and($not(%album%),%tracknumber%)),
$puts(single,1))


// playlist number configure

$puts(playlist,
$get(shadow)$repeat('0',$sub($len(%_playlist_total%),$len(%_playlist_number%)))
$get(default)%_playlist_number%' '$get(line)'|')


// setup for artist column (artist, album, etc.)

$puts(artist,
$if($stricmp($get(single),1),$get(line)$char(8195)$get(default)[%artist%],
$if($stricmp($get(first),1),
$get(line)$char(9484)$get(default)[%album artist%]$get(line)' '$repeat($char(9472),50))
$if($stricmp($get(second),1),$get(line)$char(9500)$get(default)[%album%])
$if($stricmp($get(third),1),$get(line)$char(9500)$get(default)[%date%][ / %genre%])
$if($stricmp($get(fourth),1),$get(line)$char(9492)$get(default)[$codec()])))


// setup for title column (title, filename, track artist)

$puts(title,
$get(line)
$if($stricmp($get(single),1),$char(9474),$if($stricmp($get(first),1),$char(9516),$char(9500)))
$if($stricmp($get(single),1),$get(default)%title%,
$get(default)$num(%tracknumber%,2)$get(line)' - '
$get(default)$if($meta(title),$meta(title)[ / %track artist%],$extra(filename_ext)))
$get(line)$if($stricmp($get(first),1),' '$repeat($char(9472),50)))


// bitrate setting

$puts(bitrate,
$if($info(bitrate),
$get(line)'| '
$get(shadow)$repeat(0,$sub(4,$len($info(bitrate))))
$ifgreater($info(bitrate),0,$get(gradation5),)
$ifgreater($info(bitrate),95,$get(gradation4),)
$ifgreater($info(bitrate),127,$get(gradation3),)
$ifgreater($info(bitrate),159,$get(gradation2),)
$ifgreater($info(bitrate),191,$get(gradation1),)
$ifgreater($info(bitrate),255,$get(gradation0),)
$info(bitrate)kbps))


// time display setting

$puts(time,
$get(line)' | '
$if(%_length%,$get(shadow)$cut(0:00:00,$sub(7,$len(%_length%)))$get(default)%_length%,
$if(%_time_elapsed%,
$get(shadow)$cut(0:00:00,$sub(7,$len(%_time_elapsed%)))$get(default)%_time_elapsed%)
$if($not(%isplaying%),$get(shadow)0:00:00)))


// replaygain - track gain

$puts(trackgain,
$get(line)' | '$get(default)
$puts(track_gain,$if2(%__replaygain_track_gain%,---.-- db))
$replace(
$if($stricmp($len($get(track_gain)),8),
$left($get(track_gain),1)$get(default)0$right($get(track_gain),7))
$if($stricmp($len($get(track_gain)),9),$get(track_gain)),' ',))


// replaygain - album gain

$puts(albumgain,
$get(line)' | '$get(default)
$puts(album_gain,$if2(%__replaygain_album_gain%,---.-- db))
$replace(
$if($stricmp($len($get(album_gain)),8),
$left($get(album_gain),1)$get(default)0$right($get(album_gain),7))
$if($stricmp($len($get(album_gain)),9),$get(album_gain)),' ',))


// output

$get(playlist)
$get(artist)
$tab(2)
$get(title)
$tab(3)
//$get(bitrate)
$get(time)
//$get(trackgain)
//$get(albumgain)